RedMixerChannel | SuperCollider 3.13.0 Help

Description

Represents a channel on a mixing desk. volume, panning, eq, mute, inserts, level meters etc. Can be used on its own but more often inside of a RedMixer.

Class Methods

RedMixerChannel.new(out: 0, group, lag: 0.05)

Arguments:

out	Channel index for stereo bus.
group	If `nil` then `Server.default.defaultGroup` will be used.
lag	For eq settings, balance and volume. In seconds.

RedMixerChannel.restoreFile(path)

Reads back a redMixerChannel with all settings from an archived instance. Also see -store.

NOTE: Call .init after this to initialize server side objects.

Arguments:

path	A file path as a string.

RedMixerChannel.restoreArchive(archive)

Instance Methods

.out = val

Get or set current bus.

.interp(other, val: 0)

Blend in values from another channel. Ignores out, mute, peaks and levels.

Arguments:

other	Another RedMixerChannel instance.
val	Blend fraction 0.0-1.0

.insertClass(redEfxClass, addAction: 'addToHead')

Creates a new RedEffectModule before the equalizer.

Arguments:

redEfxClass	A class or an array of classes.
addAction	Local to the inserts. The default `\addToHead` will put it first in the chain of inserts.

.insert(redEfx, addAction: 'addToHead')

Adds a RedEffectModule instance before the equalizer.

NOTE: You can not do .insert(RedEfxRing.new) without a fork.

Arguments:

redEfx	An instance or an array of instances.
addAction	Local to the inserts. The default `\addToHead` will put it first in the chain of inserts.

.removeClass(redEfxClass)

Arguments:

redEfxClass

Free and remove all instances of this RedEffectModule class. Can also be an array.

.remove(redEfx)

Arguments:

redEfx

Free and remove this RedEffectModule. Can also be an array.

.gui(parent, position)

Create a RedMixerChannelGUI.

.lag = val

Lag for this channel. Also for any equalizer parameters.

Arguments:

val	Time in seconds.

.mute = val

Mute the input sound. Post level meter.

Arguments:

val	An Integer where 1 is muted and 0 unmuted.

.def(channels: 2)

Returns the mixer channel SynthDef.

.defEq(channels: 2)

Returns the equalizer SynthDef.

.store(path)

Saves an instance as an archive to disk. All settings and effect inserts are stored. Also see *restoreFile.

Arguments:

path	A file path as a string.

.peaks

Array with maximum amplitudes. Clear with -resetPeaks.

.cvs

Dictionary with all Ref objects. (used to be CV objects)

levels	array of amplitudes
peaks	array of max amplitudes
out	output bus offset
lag	ramp time in seconds for eq settings, balance and volume
mute	silence output
amp	volume
bal	stereo balance -1 to 1
eqHi	enable highpass 0 / 1
eqMi	enable bandpass 0 / 1
eqLo	enable lowpass 0 / 1
hiFreq
hiBand
hiGain
miFreq
miBand
miGain
loFreq
loBand
loGain

.bal = val

.eqHi = val

.eqLo = val

.eqMi = val

.hiBand = val

.hiFreq = val

.hiGain = val

.loBand = val

.loFreq = val

.loGain = val

.miBand = val

.miFreq = val

.miGain = val

.restore(archive)

.vol = val

a= RedMixerChannel(0);
b= Pbind(\pan, Pseq([-1, 1], inf), \dur, 0.5, \amp, 0.5).play;
a.vol= -9
a.out= 20    //this will move and the (internal ReplaceOut) the mixerchannel to bus 20
a.out= 0    //move it back
a.lag= 1    //fade time in seconds (applies to volume, balance and all eq settings)
a.vol= 0
a.bal= -0.9
a.bal= 0.9
a.bal= 0
a.levels    //current amplitudes
a.peaks    //max amplitudes
a.resetPeaks    //reset max amplitudes to 0
a.mute= 1
a.mute= 0
a.free
b.stop

//--equalizer
a= RedMixerChannel();
a.vol= -9
b= {Pan2.ar(WhiteNoise.ar(0.5), 0)}.play;
a.eqHi= 1
a.hiFreq= 9000
a.hiBand= 0.5
a.hiGain= -20    //-20db
a.lag= 3
a.hiGain= 0    //slowly fade back to 0db
a.eqHi= 0    //as no eq active the synth will be removed
a.eqMi= 1    //recreates the eq synth
a.miFreq= 2000
a.miBand= 0.2
a.miGain= 20
a.eqLo= 1
a.loFreq= 300
a.loBand= 0.1
a.loGain= 6
a.eqMi= 0
a.eqLo= 0
a.free    //remove the channel and play sound straight though (loud)
b.free

//--inserts
s.plotTree;
g= Group(s);
a= RedMixerChannel(0, g);
b= {Pan2.ar(WhiteNoise.ar(LFNoise1.kr(4)*0.5), LFNoise1.kr(2))}.play;
c= RedEfxTank.new;
a.insert(c);
a.inserts[0].tankMix= 0;
a.insertClass([RedEfxBitc, RedEfxDist]);
a.inserts;
a.out= 1;
a.inserts[0].out;
a.out= 0
a.remove(c);
a.inserts;
a.insertClass(RedEfxRing, \addToHead);
a.insertClass(RedEfxVerb, \addToTail);
a.inserts.last.verbMix= 0.5;
a.inserts.first.ringMix= 1;
a.inserts.first.ringFreq= 0.5;
a.inserts;
a.removeClass(RedEfxVerb);
a.inserts;
a.removeAll;
a.inserts;
a.free;
b.free;
g.free;

//--interpolate
s.options.numOutputBusChannels= 8; s.reboot;
s.meter
a= RedMixerChannel(0);
b= RedMixerChannel(2);
c= Pbind(\degree, Pseq([0, 1], inf), \dur, 0.5, \amp, 0.5, \out, Pseq([0, 2], inf)).play;
b.bal= -0.75
b.lag= 0.8
b.vol= -30
a.interp(b, 0.5)
a.bal
a.lag
a.vol
a.free
b.free
c.stop

//--archive
a= RedMixerChannel();
b= {Pan2.ar(WhiteNoise.ar(0.5), 0)}.play;
a.lag= 2;
a.vol= -9;
a.eqMi= 1;
a.miGain= -20;
a.insertClass(RedEfxRing);
a.insertClass(RedEfxVerb, \addToTail);
a.inserts[0].ringMix= 1;
a.inserts[0].ringFreq= 20;
a.store("~/Desktop/redMixerChannel-test.txt".standardizePath)    //same as .writeArchive, ignore the warnings
//recompile
a= RedMixerChannel.restoreFile("~/Desktop/redMixerChannel-test.txt".standardizePath);
a.init
a.lag    //should be 2
a.vol    //shoud be -9
a.eqMi    //should be 1
a.miGain    //should be -20
a.inserts[0].ringMix
a.inserts[0].ringFreq
b= {Pan2.ar(WhiteNoise.ar(0.5), 0)}.play;    //get the same sound back
a.inserts    //should contain a RedEfxRing
a.free    //remove the channel and play sound straight though (loud)
b.free

helpfile source: /home/stefan/.local/share/SuperCollider/downloaded-quarks/redSys/HelpSource/Classes/RedMixerChannel.schelp
link::Classes/RedMixerChannel::

RedMixerChannel : Object Extension

RedMixerChannel.new(out: 0, group, lag: 0.05)

Arguments:

RedMixerChannel.restoreFile(path)

Arguments:

RedMixerChannel.restoreArchive(archive)

.group

.out

.out = val

.interp(other, val: 0)

Arguments:

.insertClass(redEfxClass, addAction: 'addToHead')

Arguments:

.insert(redEfx, addAction: 'addToHead')

Arguments:

.inserts

.removeClass(redEfxClass)

Arguments:

.remove(redEfx)

Arguments:

.removeAll

.gui(parent, position)

.free

.lag

.lag = val

Arguments:

.mute

.mute = val

Arguments:

.def(channels: 2)

.defEq(channels: 2)

.store(path)

Arguments:

.peaks

.peaks

.resetPeaks

.cvs

.archive

.bal

.bal = val

.eqHi

.eqHi = val

.eqLo

.eqLo = val

.eqMi

.eqMi = val

.hiBand

.hiBand = val

.hiFreq

.hiFreq = val

.hiGain

.hiGain = val

.levels

.loBand

.loBand = val

.loFreq

.loFreq = val

.loGain

.loGain = val

.miBand

.miBand = val

.miFreq

.miFreq = val

.miGain

.miGain = val

.restore(archive)

.vol

.vol = val

RedMixerChannel : Object
Extension