RedTween | SuperCollider 3.13.0 Help

Description

A class for mapping values between different ranges using different curvatures. It works best in combination with the Ease quark, but is also fine to use on its own. Basically it maps a value from a certain range to another range with an optional curvature.

Class Methods

RedTween.new(source: 0.0, target: 1.0, curve, inMin: 0.0, inMax: 1.0)

Arguments:

source	The beginning.
target	The destination.
curve	The curvature.
inMin	Lowest input value.
inMax	Highest input value.

Discussion:

If the curve argument is nil then a linear mapping will be used. If it is a SimpleNumber then internally a lincurve method will be applied (so the curvature will work in the same was as for the Env class). Though the real benefit of this class is to set the curve argument to an Ease object or write a custom mapping function. This allows to do proper tweening/easing.

Inherited class methods

Undocumented class methods

RedTween.ar(t ... args)

RedTween.kr(t ... args)

RedTween.value(t ... args)

Instance Methods

Inherited instance methods

Undocumented instance methods

.curve

.func

.inMax

.inMax = value

.inMin

.inMin = value

.source

.source = value

.target

.target = value

.value(t)

Examples

//--linear mapping from 0-1 to 10-20
a= RedTween(10, 20)
a.value(0)
a.value(0.5)
a.value(0.999)

//--same but with a curvature of 4
a= RedTween(10, 20, 4)
a.value(0)
a.value(0.5)
a.value(0.999)
100.collect{|x| a.value(x/99)}.plot

//--similar but map from -1 to 1 to 10-20 using a curvature of -4
a= RedTween(10, 20, -4, -1, 1)
a.value(-1)
a.value(0)
a.value(0.999)
100.collect{|x| a.value(x/99*2-1)}.plot

//--custom curvature function
a= RedTween(10, 20, {|t| t*t*t*t*t})
a.value(0)
a.value(1)
100.collect{|x| a.value(x/99)}.plot

//--ease objects
a= RedTween(-10, 20, EaseInSine)
100.collect{|x| a.value(x/99)}.plot
a= RedTween(-10, 20, EaseInAtan(20))
100.collect{|x| a.value(x/99)}.plot

//--helper method for arrays
a= [-10, 20, EaseInQuart].asRedTween
100.collect{|x| a.value(x/99)}.plot

//--the .value class method
//note how the input value is the first argument, and then the source, target, curve etc.
RedTween.value(0.55, 10, 20, {|t| t.postln; t*t*t}, 0.5, 1.0)

//--audio examples
s.boot
{SinOsc.ar(400, 0, RedTween.kr(MouseX.kr(0, 1), 0, 1, 4).poll)}.play
{SinOsc.ar(400, 0, RedTween.kr(MouseX.kr(0, 1), 0, 1, {|t| t*t*t}).poll)}.play
{SinOsc.ar(400, 0, RedTween.kr(MouseX.kr(0, 1), 0, 1, EaseInAtan).poll)}.play
{SinOsc.ar(400, 0, RedTween.kr(LFSaw.ar(0.5)*0.5+0.5, 0, 1, EaseInBack).poll)}.play

helpfile source: /home/stefan/.local/share/SuperCollider/downloaded-quarks/redSys/HelpSource/Classes/RedTween.schelp
link::Classes/RedTween::

RedTween : Object Extension