HilbertPDNRe | SuperCollider 3.13.0 Help

Description

Offers the Hilbert Transform of an input signal via Weaver's Second Method,¹ known as Hartley Phasing,² expressed as a 12th-order Phase Differencing Network.³

The Hilbert Transform, returning the first of two signals in phase-quadrature. Considered as a complex analytic signal, ⁴ the first may be regarded as the real component and the second as the imaginary.

[1] this is a composite pseudo UGen. HilbertPDNRe is built with SOS.

Class Methods

HilbertPDNRe.ar(in, mul: 1.0, add: 0)

Arguments:

in	The input signal to transform.
mul	Output will be multiplied by this value.
add	This value will be added to the output.

Returns:

The real part of the Hilbert Transform.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

FFT analysis functions

NOTE: FFT returns linear frequency

*/
(
~calcMag = { arg kernel;

var fftResponse, fftMag;

// FFT analysis here!
    fftResponse = fft(
        kernel.as(Signal),
        Signal.newClear(kernel.size),
        Signal.fftCosTable(kernel.size)
    );

// find (& trim magnitude)
    fftMag = fftResponse.magnitude;
    fftMag = fftMag.copyFromStart((kernel.size/2).asInteger);

fftMag;
};
)

/*
        TEST PDN : HilbertPDNRe

Impulse Response
*/
(
var size, dur, freq;
var overSample, start;
var plotDbMin, plotDbMax;

// kernel size
size = 2048;

overSample = 2;

// plot params
plotDbMin = -60.0;
plotDbMax = 6.0;

start = 0;  // offset - for kernel normalized to sample delay

dur = size / s.sampleRate;  // in seconds
freq = dur.reciprocal;

fork {
    { // real
        HilbertPDNRe.ar(
            Impulse.ar(freq, 0.5) // imulse test, one pulse over fftbuffer size
        );
    }.loadToFloatArray(overSample * dur, s, {
        |arr|
        defer {
            arr = arr.copyRange(start, start+size-1);
            arr.plot("Real; HilbertPDNRe; Impulse input", minval: -1, maxval: 1);
        }
        }
    );

0.5.wait;

{ // plot magnitude - real
        HilbertPDNRe.ar( // real
            Impulse.ar(freq, 0.5) // imulse test, one pulse over fftbuffer size
        );
    }.loadToFloatArray(overSample * dur, s, {
        |arr|
        defer {
            arr = arr.copyRange(start, start+size-1);
            ~calcMag.value(arr).ampdb.plot(
                name: "Real Magnitude Response",
                minval: plotDbMin,
                maxval: plotDbMax
            );
        }
        }
    );

}
)

/*
        TEST PDN : HilbertPDNRe

single cosine cycle: period = size
*/

(
var size, dur, freq;
var overSample, start;

size = 2048;
overSample = 4;

// plot: adjust "by hand":
// 1) account for "warm up" of Re & Im
// 2) account for non-linear phase response of PDN
start = size + 779;  // size = 2048, sampleRate = 44100

dur = size / s.sampleRate;  // in seconds
freq = dur.reciprocal;

{ // real
    HilbertPDNRe.ar(
        SinOsc.ar(freq, pi/2), // cosine test, one cycle over fftbuffer size
        );
}.loadToFloatArray(overSample * dur, s, {
    |arr|
    defer {
        arr = arr.copyRange(start, start+size-1);
        arr.plot("Real; HilbertPDNRe; Cosine input", minval: -1, maxval: 1);
    }
}
);
)

Frequency response

Please review the discussion found here.

[1] - Weaver, Donald. “A Third Method of Generation and Detection of Single-Sideband Signals.” Proceedings of the IRE, vol. 44, no. 12, 1956, pp. 1703–1705.

[2] - US Patent 1,666,206, Modulation System, April 17, 1928, United States Patent and Trademark Office.

[3] - B. Hutchins, “The Design of Wideband Analog 90° Phase Differencing Networks without Large Spread of Capacitor Values”, Electronotes, Special Issue G, No. 168, http://electronotes.netfirms.com/EN168-90degreePDN.PDF, accessed 2017-08-08.

[4] - Smith, J.O. “Analytic Signals and Hilbert Transform Filters”, in Mathematics of the Discrete Fourier Transform (DFT) with Audio Applications, Second Edition, https://ccrma.stanford.edu/~jos/st/Analytic_Signals_Hilbert_Transform.html, online book, 2007 edition, accessed 2017-08-08.

helpfile source: /home/stefan/.local/share/SuperCollider/downloaded-quarks/Hilbert/HelpSource/Classes/HilbertPDNRe.schelp
link::Classes/HilbertPDNRe::

HilbertPDNRe : Object Extension